Lets people talk to Wardrik's agents from chat apps, such as Slack.

A channel is one chat app Wardrik runs, under a name you choose. A room is a place in it, such as a Slack channel.

config :my_app, MyApp.AgentRuntime,
  channels: [
    slack: {WardrikSlack, token: "xoxb-...", signing_secret: "...", owner: "acme", approvers: ["@maria"]}
  ]

An agent answers in a channel when its definition lists it:

Wardrik.Agent.define(scope, "acme/triage", model: "anthropic:claude-haiku-4-5", channels: ["slack"])

Mention the bot in a room to start a thread. Reply in the thread to go on. Each thread is its own conversation, as acme/triage/slack.T0123.C024BE91L.1696.1234. Calls the agent waits on are posted in the thread for someone to decide. See WardrikChannel.Rooms and WardrikChannel.Replies.

Options

Every channel takes these. Its adapter reads the rest.

• :token - the token the channel acts with, in the one workspace it reaches. Needs :owner.
• :owner - whose agents answer, as "acme".
• :installations - instead of :token, to add one app to many workspaces. Either :stored, to keep them in Wardrik (needs Wardrik's :keys), or {module, config}, a Wardrik.Channel.Installations.
• :approvers - who may decide what agents wait on, as the chat app names people, or :anyone. [] unless set. Whoever asked for a turn may always decide it.
• :offering - what a room with no agent is told.
• :deciding - what someone who may not decide is told.

Raises ArgumentError on start if neither or both of :token and :installations are given, or if the channel's name isn't lower-case letters, digits and -, starting with a letter.

Writing an adapter

An adapter is a package, such as wardrik_slack, that does use WardrikChannel. It implements deliver/2 and include?/4, and Wardrik.Channel.request/2 to take what the chat app sends:

defmodule MyChat do
  use WardrikChannel

  @impl Wardrik.Channel
  def request(opts, %{path: "events", body: body}) do
    channel = WardrikChannel.channel(__MODULE__, opts)
    event = JSON.decode!(body)

    with {:ok, workspace} <- WardrikChannel.workspace(channel, event["team"]) do
      WardrikChannel.received(workspace, %WardrikChannel.Inbound{
        room: event["room"],
        id: event["id"],
        sender: %WardrikChannel.Member{id: event["user"]},
        text: event["text"],
        mentioned?: event["mentioned"]
      })
    end

    %{status: 200, headers: %{}, body: ""}
  end

  @impl WardrikChannel
  def deliver(channel, %WardrikChannel.Outbound{} = outbound) do
    # Post outbound.body in outbound.room, in outbound.thread
    :ok
  end

  @impl WardrikChannel
  def include?(_channel, _installation, names, member), do: member.id in names
end

Hand each button press to decide/4. use WardrikChannel defines child_spec/1, children/1 and Wardrik.Channel.notify/4. Each can be overridden.